Bon2Gradle

buildscript {
    repositories {
        // Добавьте JitPack.io в ваши репозитории сборки
        maven { url 'https://jitpack.io' } 
        
        // Вещи для ForgeGradle
        maven { 
            name 'forge'
            url 'https://maven.minecraftforge.net/'
        }
    }
    dependencies {
        // Вещи для ForgeGradle (форк anatawa12)
        classpath('com.anatawa12.forge:ForgeGradle:1.2-1.0.+') {
            changing = true
        }

        // Добавьте плагин в зависимости, можете использовать "master-SNAPSHOT" как версию, чтобы
        // использовать последний коммит. 
        classpath 'com.github.MJaroslav:Bon2Gradle:0.3.1'
    }
}

apply plugin: 'bon2gradle' // Подключение плагина

// Расширение для настройки BON2
// опция = значенеи по умолчанию // описание
bon2 {
    useParallelDeobfuscation = false // Если зависимость состоит из нескольких файлов,
    // Они будут деобфусцированы параллельно. EXPERIMENTAL
    forceMapping = false // Использовать только следующий маппинг для зависимостей.
    forcedMappingLocation = null // Директория с файлами methods.csv и fields.csv.
    forcedMappingRelativeConfPath = null // Дополнительный относительный путь для параметра выше.
    // ^ Будет использовано значение 'unpacked/conf' если не параметр не представлен ^
    
    mappingProvider = 'io.github.mjaroslav.bon2gradle.api.impl.FG12Provider'
    // Просто реализация интерфейса 'io.github.mjaroslav.bon2gradle.api.MappingProvider'
    // Для получения текущего маппинга вашего Minecraft проекта.     
}

repositories {
    mavenCentral()
    maven {
        url "https://cursemaven.com/"
        content {
            includeGroup "curse.maven"
        }
    }
}

dependencies {
    // Мод HEE из репозитория cursemaven просто для примера
    // Все деобфусцированные jar'ы будут сохранены в специальной директории внутри build директории проекта.
    implementation bon2.deobf("curse.maven:hardcore-ender-expansion-228015:2316923")
}